【ESP32】5Vピンについて

akizukidenshi.com

秋月で売られているこのESP32-DevKitC、回路図の例などを調べると3V3が電源というのは様々なサイトで書かれていますが、5Vと書かれたピンが何を意味しているのかを今まで知らなかったので今回メモしておきます。

■5Vピンの謎
　結論から言うと、5Vピンの先には3.3Vに降圧するレギュレーターが入っているので5V以上でも動きます。
（「3V3が電源」という内容で書かれた記事や回路図が多いので混乱しがちですが、USBからの給電が5Vなのでそれを降圧する必要がありレギュレーターは必須なのです……）

　上記商品ページにある回路図を見ると「NCP1117」というレギュレーターが使われています。そのデータシートは以下になります。

　NCP1117 pdf, NCP1117 ディスクリプション, NCP1117 データシート, NCP1117 view ::: ALLDATASHEET :::

　これを読むとどうやら20Vぐらいまではいけるようです（未検証）。

　実験として8V程度を5Vピンに入れてやっても焼けることはなかったので、大丈夫です。ただしどれぐらい発熱するかはわからないので、6Vぐらいまでにしておいた方が良いかもしれません。

【ESP32】PWMでモーターを制御する方法

ESP32でPWM制御をやってみました。ESP32ではPWM用のピンがあるわけではなく、ソフト側でPWMの設定を行います。

１：ESP32でのPWMの使い方
　ledcSetup、ledcAttachPin、ledcWriteの関数を使用します。
　ledcSetupでPWMの設定、ledcAttachPinでチャンネルとピンを対応、ledcWriteで実行という流れです。

// １：ledcSetup(チャンネル, 周波数, PWMの範囲);
ledcSetup(0, 490, 8);

// ２：ledcAttachPin(ピン番号, チャンネル);
ledcAttachPin(7, 0);

// ３：ledcWrite(チャンネル, PWM値);
ledcWrite(0, 255);

※ledcSetupでのPWMの範囲は、8(8bit)を設定した場合は0〜255、10(10bit)の場合は0〜1023になります。

　これでPWMの使い方がわかったので、ESP32でモーターの制御をやっていきます。

１：材料
・電池ボックス
電池ボックス 単３×２本 リード線・スイッチ付: パーツ一般 秋月電子通商 電子部品 ネット通販

・モータードライバ（半田付けが必要）
ＤＲＶ８８３５使用ステッピング＆ＤＣモータドライバモジュール: 組立キット 秋月電子通商 電子部品 ネット通販

・モーター
ＤＣモーター ＦＡ−１３０ＲＡ−２２７０: パーツ一般 秋月電子通商 電子部品 ネット通販

・単3電池2本

２：プログラム

/* 使うピンの定義 */
const int IN1 = 25;
const int IN2 = 26;

/* チャンネルの定義 */
const int CHANNEL_0 = 0;
const int CHANNEL_1 = 1;

const int LEDC_TIMER_BIT = 8;   // PWMの範囲(8bitなら0〜255、10bitなら0〜1023)
const int LEDC_BASE_FREQ = 490; // 周波数(Hz)
const int VALUE_MAX = 255;      // PWMの最大値

void setup() {
  pinMode(IN1, OUTPUT); // IN1
  pinMode(IN2, OUTPUT); // IN2

  // ピンのセットアップ
  ledcSetup(CHANNEL_0, LEDC_BASE_FREQ, LEDC_TIMER_BIT);
  ledcSetup(CHANNEL_1, LEDC_BASE_FREQ, LEDC_TIMER_BIT);

  // ピンのチャンネルをセット
  ledcAttachPin(IN1, CHANNEL_0);
  ledcAttachPin(IN2, CHANNEL_1);
}

void loop() {
  forward(255); // 正転
  delay(3000);
  coast();      // 空転
  delay(3000);
  reverse(100); // 逆転
  delay(3000);
  brake();      // ブレーキ
  delay(3000);
}

// 正転
void forward(uint32_t pwm) {
  if (pwm > VALUE_MAX) {
    pwm = VALUE_MAX;
  }
  ledcWrite(CHANNEL_0, pwm);
  ledcWrite(CHANNEL_1, 0);
}

// 逆転
void reverse(uint32_t pwm) {
  if (pwm > VALUE_MAX) {
    pwm = VALUE_MAX;
  }
  ledcWrite(CHANNEL_0, 0);
  ledcWrite(CHANNEL_1, pwm);
}

// ブレーキ
void brake() {
  ledcWrite(CHANNEL_0, VALUE_MAX);
  ledcWrite(CHANNEL_1, VALUE_MAX);
}

// 空転
void coast() {
  ledcWrite(CHANNEL_0, 0);
  ledcWrite(CHANNEL_1, 0);
}

３：回路図

　上記のように繋げばモーターが正転、逆転を始めます。PWMの値を変更すると、モーターの回転数も変化します。

　ESP32が3Vで駆動できるので、それに合わせて低い電圧でも動くモータードライバを選びました。基盤が熱くなると注意書きがありますが、3V程度の使用であれば問題はないようです。低電圧でも動くモータードライバもいいですね。

【ESP32】data.sparkfun.comにESP32から値を送る方法

data.sparkfun.com公式

「data.sparkfun.com」というIoT用の無料で使えるサイトを知ったのでESP32から値を送ってみました。今回はその方法をまとめていきます。

１：data.sparkfun.comでストリームを作成する
　data.sparkfun.comにアクセスし、createボタンを押します。移動先のページで各項目を入力することで値を送るストリームを作成できます。

項目名	内容	必須
Title	作成するストリームのページに表示されるタイトル	◯
Description	作成するストリームのページの表示される詳細な説明	◯
Show in Public Stream List?	Visibleの場合は全体リストに公開、Hiddenの場合は非公開	◯
Fields	値を受け取る変数名	◯
Stream Alias	エイリアスの設定。sensorと入力するとhttp：//data.sparkfun.com/sensorでアクセスできる	×
Tags	タグの設定	×
Location	場所の設定	×

上記の入力が終了しSaveボタンを押すと、必要なキーや値を送る例を表示したページに移動します。各値は忘れないようにメモしておきます。

ちなみに各項目の内容は以下の通りです。

項目名	内容
Public URL	作成されたストリームのURL。ここで送られた値を確認する
Public Key	ストリームからデータを取り出す時に必要なキー
Private Key	ストリームにデータを送る時に必要なキー
Delete Key	ストリームを削除する時に必要なキー
Format	ストリームにデータを送る時のフォーマット
Example	Formatに合わせた具体例

２：ESP32をネット接続してストリームに値を送信する
１でストリームが完成したら、FormatにしたがってESP32からネット経由で値を送信します。具体的にはESP32に以下のソースを書き込めば実現できます。

・Sparkfun.ino

#include <WiFi.h>

const char* ssid     = "***";       // インターネットに接続できるWiFiのSSID
const char* password = "***";  // SSIDのパスワード

const char* publicKey = "*****";  // ストリーム作成時に払い出されたPublic Key
const char* privateKey = "*****"; // ストリーム作成時に払い出されたPrivate Key
const char* fields = "field";          // ストリーム作成時に設定したFields

const char* host = "data.sparkfun.com";  // host

WiFiClient client;

void setup() {
  Serial.begin(115200);
  
  // WiFiに接続
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)  {
    Serial.print(".");
    delay(1000);
  }
  Serial.print("Connected to ");
  Serial.println(ssid);

  if (client.connect(host, 80)) {
    int val = 100;  // 今回は100という数値を送信

    // Formatに合わせたURLを作成
    String url = String("/input/")
                  + publicKey + "?private_key="
                  + privateKey + "&" + fields + "=" + val;

    // URLを発行
    client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                 "Host: " + host + "\r\n\r\n");
    delay(1000);

    while (client.available()) {
      Serial.print(client.readStringUntil('¥r'));  // 結果のhtmlを表示
    }
  } else {
    Serial.println("Connection failed!");
  }
}

void loop() {
}

WiFiに接続した後に100という値を送信するURLを作成し発行します。その結果のhtmlをシリアルモニタに表示させています。

以上の方法で値をストリームに送信できます。ストリームから値を取得したり削除したりはまだ試していませんが、いわゆるIoTっぽいことがこれでできるようになります。ストリームを使って色々値のやりとりできたら楽しいですね。

※追記：ストリームからの値取得
ストリームからの値を取得することもできたので修正したソースを追記しておきます。

・Sparkfun2.ino

#include <WiFi.h>

const char* ssid     = "****";
const char* password = "****";
const char* publicKey = "*****";
const char* privateKey = "*****";
const char* fields = "field";
const char* host = "data.sparkfun.com";

WiFiClient client;

// 引数の値を送信する関数(全角文字はストリームに送信できない。失敗する)
void sendDataToSparkfun(String val) {
  String url = String("/input/")
                + publicKey + "?private_key="
                + privateKey + "&" + fields + "=" + val;
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
             "Host: " + host + "\r\n\r\n");
  // 結果を表示
  while (client.available()) {
    Serial.print(client.readStringUntil('¥r'));
  }
}

// ストリームの値を取得する関数
void getDataFromSparkfun() {
  String url = String("/output/") + publicKey + ".csv?page=1";
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                "Host: " + host + "\r\n\r\n");
  // 結果を表示
  while (client.available()) {
    Serial.print(client.readStringUntil('¥r'));
  }
}

void setup() {
  Serial.begin(115200);
  
  // WiFiに接続
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)  {
    Serial.print(".");
    delay(1000);
  }
  Serial.print("Connected to ");
  Serial.println(ssid);

  if (client.connect(host, 80)) {
    String value = "1111"; // 1111を送信
    sendDataToSparkfun(value);
    delay(1000);
    getDataFromSparkfun();
  } else {
    Serial.println("Connection failed!");
  }
}

void loop() {
}

※Arduino IDEでのコンパイル時に特におかしなところがないのに「"関数名" was not declared in this scope」というエラーが発生した場合、setup関数よりも前にエラーが出た関数を移動させるとコンパイルが通るという現象もあるようです。

【ESP32】ESP32とスマホを接続してWiFiUDP通信する方法

rikoubou.hatenablog.com

↑の前回の記事でESP32を使って以降、ESP32をいじっています。今回はタイトル通り「ESP32とスマホを繋いでUDP通信する方法」をやってみたので記録しておきます。

１：ESP32とUDP通信できるようにする
基本的にはWiFiをアクセスポイント(APモード)で使用するプログラムを少し変更するだけでできます。以下がプログラムになります。

・ESP32_WiFiUDP.ino

#include <WiFi.h>
#include <WiFiUdp.h>

const char ssid[] = "ESP32_wifi"; // SSID
const char pass[] = "esp32pass";  // password
const int localPort = 10000;      // ポート番号

const IPAddress ip(192, 168, 4, 1);       // IPアドレス(ゲートウェイも兼ねる)
const IPAddress subnet(255, 255, 255, 0); // サブネットマスク

WiFiUDP udp;

void setup() {
  Serial.begin(115200);

  WiFi.softAP(ssid, pass);           // SSIDとパスの設定
  delay(100);                        // 追記：このdelayを入れないと失敗する場合がある
  WiFi.softAPConfig(ip, ip, subnet); // IPアドレス、ゲートウェイ、サブネットマスクの設定

  Serial.print("AP IP address: ");
  IPAddress myIP = WiFi.softAPIP();
  Serial.println(myIP);

  Serial.println("Starting UDP");
  udp.begin(localPort);  // UDP通信の開始(引数はポート番号)

  Serial.print("Local port: ");
  Serial.println(localPort);
}

void loop() {
  if (udp.parsePacket()) {
    Serial.println(udp.read()); // UDP通信で来た値を表示
  }
}

WiFiUdp.hを読み込んで使用します。ポート番号とIPアドレスは固定させていた方が良いと思います。

上記のプログラムを書き込むとSSIDで指定した名前でWiFiが飛ぶようになります。passwordで設定したパスを入力すれば接続できます。

２：スマホにアプリを入れてUDPコントローラを作成する
次にスマホをUDPコントローラとして使うためのアプリ「WiFi TCP/UDP Controller」を以下のリンクからインストールします。
play.google.com

インストール後にWiFi TCP/UDP Controllerを立ち上げるとDEFと書かれた多くのボタンが表示されます。最初は何も設定されていないので、右上にある「PREFERENCE」をタップして各ボタンの設定を行います。

・IP or Domain Name
　IPアドレスやドメイン名を設定します。１のプログラムそのままの場合は「192.168.4.1」と設定します。

・Port
　ポート番号を設定します。１のプログラムそのままの場合は「10000」と設定します。

・BUTTON　Name
　画面に表示されるボタン名を設定します。設定画面に移動したときに出てくる画像通りの並び順なので、それぞれのボタンに表示させたい名前を設定します。自分の場合は以下のように設定しました。

ボタン名	表示名
button2	▲
button4	◀︎
button6	▶︎
button8	▼
button19	B
button21	A

・BUTTON　Command
　ボタンを押した際に送信する値を設定します。設定画面に移動したときに出てくる画像通りの並び順なので、それぞれのボタンに表示させたい名前を設定します。ASCII-HEXでは文字列を送信する場合は「ASCII」、数値を送信する場合は「HEX」を選びます。

自分の場合は以下のように設定しました。

項目名	設定値
ASCII-HEX	ASCII
button2	0
button4	1
button6	2
button8	3
button19	4
button21	5

　STOP COMMANDではボタンを離したときに送信される値を設定します。自分の場合は以下のように設定しました。

項目名	設定値
button2	6
button4	6
button6	6
button8	6
button19	6
button21	6

・BUTTON　Visibility
　ボタンの表示/非表示を設定します。デフォルトでは全てのボタンが表示されているので、不要なボタンは非表示にします。自分の場合は以下のように設定しました。

項目名	チェック
button2	レ
button4	レ
button6	レ
button8	レ
button19	レ
button21	レ

上記以外のチェックは全て外しています。

・BUTTON　Repeatable
　ボタンを押している間の送信時間間隔を設定します。個別のボタンごとに設定もできますが、自分の場合は以下のように設定しました。

項目名	設定値
Individual Intervals	OFF
Interval（ms）	200

・Send Data
　送った値を画面下に表示させるかどうかを設定します。自分の場合はONにしています。

・設定完了例
　自分が作成したコントローラは以下のようになります。各ボタンを押したときに上にある数字が送信されます。全てのボタンにおいて離したときに6が送信されるようにしています。

３：ESP32とスマホを接続して通信を確認する
１のプログラムを書き込んだESP32をUSBで接続し、シリアルモニタを立ち上げます。ESP32のSSIDのWiFiにスマホで接続し、２で作成したコントローラのボタンを押すとその値がシリアルモニタに表示されます。（今回はASCIIで送信しており、数字の文字列が送信されているので、ASCIIの対応表で数字を変換してください）

・このような形で押したボタンの値が表示されていきます。

以上でESP32とスマホ間でのUDP通信ができました。
ESP32にディスプレイを繋げば簡単なゲームも作成できる（している方もいる）ので色々と面白いことができそうです。

・参考資料
github.com

www.nicovideo.jp

【ESP32】ゼルダエフェクトーンを自作してみた

www.bpnavi.jp

ツイッター上で話題になったゼルダエフェクトーン。
見た瞬間に「これ作れそう」と思って材料を購入し、勢いで自作しました。
使った材料や回路図を記録する意味でも記事にしておきます。

※電子回路もプログラムも知識が浅いため、ツッコミどころが多いと思います。注意してください

・追記：回路とプログラムの改良版ができました
rikoubou.hatenablog.com

１：材料
以下が今回使用した材料です。合計2500円ぐらいです。

・ESP32-DevKitC（以下記事内ではESP32と記述）　商品ページ
・20ピン基板用ピンソケット[20ピン×1列]【21601X20GSE】×２　商品ページ
　（ESP32の片側の足は19本なので一つ余る）
・ユニバーサル基盤（ICB288）　商品ページ
・電池ケース 単4×2本（BH421A）　商品ページ
・圧電ブザー（buz-1.5-9.5mm）　商品ページ
・ケース入りリードスイッチ（磁石付セット）ＭＣ－１４ＡＧ　商品ページ
・基板用スライドスイッチ(横型)【GB-SSW-SPDT-RAGL】　商品ページ
・SW型プラスチックケース【SW85S】　商品ページ
・３ｍｍプラスチックネジ（７ｍｍ）＋ナットセット　商品ページ

※あと半田ごてとか接着剤とか電動ドリルとか単４電池とかもろもろ

２：回路図

ものすごく単純な回路です。
単４ケースは、ユニバーサル基盤にドリルで穴を開けてプラスチックのネジとナットで基盤自体に固定させています。

３：ケースの加工
電源スイッチをケースの外に出す必要があるので、以下の写真のように側面に穴を開けます。

４：ESP32へプログラムを書き込む
前提としてESP32が使用できる環境が必要です。
【備忘録】ESP-32 DevKitCの環境構築方法 - ソースに絡まるエスカルゴ

ESP32に書き込むプログラムは以下の通りです。

・Effectone.ino

#define BUZZER_PIN 23       // ブザーを鳴らすためのピン
#define MAGNET_PIN 12       // 磁石スイッチのHIGHを出力するピン
#define JUDGE_PIN 14        // 磁石スイッチの判断をするピン

#define BEAT 150            // 一つの音を鳴らす時間
#define LEDC_CHANNEL 0      // チャンネル
#define LEDC_TIMER_BIT 13
#define LEDC_BASE_FREQ 5000

bool soundFlg = false; // 音を鳴らしたかどうかのフラグ

void setup() {
  // マグネットスイッチに関係するピンの準備
  pinMode(MAGNET_PIN, OUTPUT);
  pinMode(JUDGE_PIN, INPUT);

  // マグネットスイッチのをHIGHにする
  digitalWrite(MAGNET_PIN, HIGH);
  
  // 音を鳴らす準備
  ledcSetup(LEDC_CHANNEL, LEDC_BASE_FREQ, LEDC_TIMER_BIT);
  ledcAttachPin(BUZZER_PIN, LEDC_CHANNEL);
}

void loop() {
  int val = digitalRead(JUDGE_PIN);
  if (!soundFlg && val == LOW) {
    callZeldaSound();   // ゼルダの謎解き音を鳴らす
    soundFlg = true;
  } else if (val == HIGH) {
    soundFlg = false;
  }
  delay(100);
}

/**
 * ゼルダの謎解き音
 */
void callZeldaSound() {
  ledcWriteTone(LEDC_CHANNEL, 3136); // ソ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 2960); // ♯ファ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 2489); // ♯レ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 1760); // ラ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 1661); // ♯ソ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 2637); // ミ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 3322); // ♯ソ
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 4186); // ド
  delay(BEAT);
  ledcWriteTone(LEDC_CHANNEL, 0);    // 音を止める
}

ESP32ではブザーを鳴らす関数としてledcWriteToneを使います。

・参考記事
ESP-WROOM-32

５：ケースにつめる
基盤の実装とESP32へのプログラムの書き込みが終了したら、次はケースに詰めます。SW85Sにはネジ穴はついてないので、接着剤でナットをケースの底に固定させています。位置が確定したら、フタを被せてブザーが来る位置に穴を開けます。

６：完成したので遊ぶ
動かすとこんな感じになります。

とりあえず自作ゼルダエフェクトーンできた（音量小さめかも） pic.twitter.com/cswS3jY7AW

— シン・ほいっぷ (@sin_deviding) 2017年5月29日

リードスイッチは振動に弱いらしく、現状のプログラムのままだとケースを振るだけで音が鳴ります。また音も小さいので、穴を増やしたり大きくしたりした方が良いかもしれません。

以上が今回作ってみた自作ゼルダエフェクトーンになります。プログラムを修正すれば他の音も鳴らせますし、ESP32はWifiやBluetooth接続もできるのでさらに遊べると思います。（正直今回程度のことを実現するならオーバースペックすぎますし……）

ブザーを増やして和音を鳴らせたりするのも面白いかもしれません。

【備忘録】KKHMF LM393 IR赤外線障害物回避センサモジュール Arduino用について

amazonで見つけた怪しいぐらいに安い距離センサー（KKHMF LM393 IR赤外線障害物回避センサモジュール Arduino用）についての備忘録です。

下記商品ページのレビューにある内容と実際のものがちょっと違っていたので記録しておきます。
Amazon CAPTCHA

■大体の仕様
結論部分だけまとめると以下のようになります。

物理的距離	OUTの出力	輸出表示のLED
設定距離より遠い	HIGH	消灯
設定距離より近い	LOW	点灯

可変抵抗を回して設定距離を変更可能。
判定はOUTのデジタル出力HIGH or LOWで判断。

• OUTがHIGH　：　設定距離より遠い
• OUTがLOW　 ：　設定距離より近い

「輸出表示」と文字のある部分のLEDが光っている時は近い、光っていない時は遠いと見た目でもわかるようになっている。可変抵抗を反時計回りに回すと設定距離が短く、時計回りに回すと設定距離が長くなる。

※ただし、どちらの場合でも可変抵抗を限界まで回すと検知できなくなるので注意

単に近いかどうかを判定するだけなら十分使えるセンサーだと思います。
これで何かを作りたいですね。

【備忘録】ESP-32 DevKitCでのWiFi接続方法（APモード）

APモードのESP-32にWiFi接続する方法を残しておこうと思った次第です。

というのも、

• esp8266で使っていたソースが流用できない。
• サンプルにAPモードでの接続のものが見当たらない。

という状況だったので、まとめようと決意しました。

では以下に方法をまとめていきます。
※一つ前の記事で環境構築が済んでいることが前提です。

■ESP-32でAPモードでWiFiを起動するソース

結論から言うと、以下のソースでいけます。

ESP32_WiFi.ino

#include <WiFi.h>

WiFiServer server(80);

const char ssid[] = "ESP32-WiFi";  // SSID
const char pass[] = "esp32wifi";   // password

const IPAddress ip(192, 168, 20, 2);      // IPアドレス
const IPAddress subnet(255, 255, 255, 0); // サブネットマスク

void setup() {
  Serial.begin(115200);

  WiFi.softAP(ssid, pass);           // SSIDとパスの設定
  delay(100);                        // 追記：このdelayを入れないと失敗する場合がある
  WiFi.softAPConfig(ip, ip, subnet); // IPアドレス、ゲートウェイ、サブネットマスクの設定
  
  IPAddress myIP = WiFi.softAPIP();  // WiFi.softAPIP()でWiFi起動
  server.begin();                    // サーバーを起動(htmlを表示させるため)

  /* 各種情報を表示 */
  Serial.print("SSID: ");
  Serial.println(ssid);
  Serial.print("AP IP address: ");
  Serial.println(myIP);

  Serial.println("Server start!");
}

void loop() {
  WiFiClient client = server.available();
  
  if (client) {
    String currentLine = "";
    Serial.println("new client!");
    while (client.connected()) {
      if (client.available()) {  
        if (currentLine.length() == 0) {
          client.println("HTTP/1.1 200 OK");
          client.println("Content-type:text/html");
          client.println();
          client.println("hello!");
          break;
        } else {
          currentLine = "";
        }
      }
    }

    // 接続が切れた場合
    client.stop();
    Serial.println("client disonnected");
  }
}

上記のプログラムをESP-32 DevKitCに書き込むと、ESP32-WiFiというWiFiが飛ぶようになります。
それを選択し、passで設定したパスワードを入力すると接続完了です。

その状態でブラウザを開いて、IPアドレスに設定した192.168.20.2に接続すると「hello!」と表示されます。

SSID、pass、ipなどは定数になっているので任意に変更することができます。

・2017/07/18　追記
　久々にWifiのAPモードをESP32で実行しようとしたところ、なぜか起動しないという不具合が確認できました。色々調べて行くと「WiFi.softAPのあとにdelayを入れないと失敗する場合がある」ことがわかりました。
　なので上記プログラムにdelayを追記しています。

　抜粋すると以下の部分になります。

WiFi.softAP(ssid, pass);           // SSIDとパスの設定
delay(100);                        // 追記：このdelayを入れないと失敗する場合がある
WiFi.softAPConfig(ip, ip, subnet); // IPアドレス、ゲートウェイ、サブネットマスクの設定

・参考ページ
github.com