ソースに絡まるエスカルゴ

貧弱プログラマの外部記憶装置です。

【ESP32】マルチタスクについて

 ESP32でマルチタスクをする方法を探していたら見つけたので記録しておきます。

■ESP32でマルチタスクを行うプログラム
 基本的には参考記事のところにあるソースで良いのですが、なぜか自分のに書き込むと動かなかったので少し修正しました。

int maincount = 0; // メインカウンタ

// 裏で動かすタスク
void testTask(void *pvParameters) {
  int subcount = 1000; // サブカウンタ
  while(1) {
    Serial.println("sub task " + String(subcount));
    subcount++;
    delay(1000);
  }
}

void setup() {
 Serial.begin(115200);
 // タスクの登録(1とある引数が多分タスクのナンバリング)
 xTaskCreate(testTask,"testTask", 1024, NULL, 1, NULL);
}

void loop() {
  // loopの中では別の処理
  Serial.println("arduino loop "+ String(maincount));
  maincount++;
  delay(1000);
}

 上記をESP32に書き込んでからシリアルモニタを立ち上げると、以下のように二つのカウントアップ文字列が表示されます。
f:id:rikoubou:20170612153723p:plain


■参考記事
なんか作ろうよ ESP-WROOM-32でマルチタスク

■追加情報
マルチタスクでさらにわかったことを記事にしました。
rikoubou.hatenablog.com

【ESP32】赤外線通信について

 ESP32で赤外線を使って色々やってみようと思ったですが、ArduinoUnoで使えていたライブラリ等がESP32ではまだないようです。
 色々調べて行くとライブラリを使わずに赤外線通信を行なっている記事を見つけたので、それを元にESP32で動かした時のことを備忘録として記録しておきます。


・2017/06/27追記:より実用的な方法の記事を書きました
rikoubou.hatenablog.com



1:材料
 今回自分が使ったのは以下のものですが、すべての材料は安いものでも大丈夫だと思います。

・赤外線LED
3φ砲弾型赤外線LED 940nm LIR034の通販ならマルツオンライン

・赤外線受光器
リモコン受光モジュール RPM7138-Rの通販ならマルツオンライン

・適当な単色LED
・ESP32-DevKitC×2
・単3電池ボックス(必要に応じて)
・200Ω程度の抵抗×2
・ブレッドボード×2


2:受信側について
・プログラム

#define READ_PIN 26
#define LOW_STATE 0
#define HIGH_STATE 1
 
void setup(){
  Serial.begin(115200);
  pinMode(READ_PIN,INPUT);
 
  Serial.println("Ready to receive");
}
 
void waitLow() {
  while (digitalRead(READ_PIN)==LOW) {
    ;
  }
}
 
int waitHigh() {
  unsigned long start = micros();
  while (digitalRead(READ_PIN)==HIGH) {
    if (micros() - start > 5000000) {
      return 1;
    }
  }
  return 0;
}
 
unsigned long now = micros();
unsigned long lastStateChangedMicros = micros();
int state = HIGH_STATE;
 
void loop() {
    if (state == LOW_STATE) {
      waitLow();
    } else {
      int ret = waitHigh();
      if (ret == 1) {
        Serial.println("");
        return;
      }
    }
 
    now = micros();
    Serial.print((now - lastStateChangedMicros) / 10, DEC);
    Serial.print(",");
    lastStateChangedMicros = now;
    if (state == HIGH_STATE) {
      state = LOW_STATE;
    } else {
      state = HIGH_STATE;
    }
}

 基本的には参考記事にあるものそのままです。

 回路は、材料にあげたのと同じものを使うのであれば、以下の赤外線受光器のデータシートにあるように繋ぎます。
f:id:rikoubou:20170612140529p:plain

 シリアルモニタを立ち上げてESP32のリセットボタンを押すと、「Ready to receive」が表示されます。
 この状態で赤外線受光器にリモコンを向けてボタンを押すと数値の羅列が表示され、受信できていることが確認できます。


3:送信側について
・プログラム

const int IR_SEND_PIN = 33; // 赤外線LEDのピン
const int LED_PIN = 25;     // LEDのピン

// 送信データ
unsigned int data[] = {1000,2000,3000,4000,5000,6000,7000};

void setup() {
  pinMode(IR_SEND_PIN, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  digitalWrite(LED_PIN, HIGH);
  sendSignal(); // 赤外線信号を送信
  digitalWrite(LED_PIN, LOW);
  delay(3000);
}

// dataの赤外線信号を送信
void sendSignal() {
  int dataSize = sizeof(data) / sizeof(data[0]);
  for (int cnt = 0; cnt < dataSize; cnt++) {
    unsigned long len = data[cnt]*10;
    unsigned long us = micros();
    do {
      digitalWrite(IR_SEND_PIN, 1 - (cnt&1));
      delayMicroseconds(8);
      digitalWrite(IR_SEND_PIN, 0);
      delayMicroseconds(7);
    } while (long(us + len - micros()) > 0); // 送信時間に達するまでループ
  }
}

 こちらも参考記事にあるものほぼそのままです。

 回路図も書くほどではないので省きます。LEDの足の長い方と出力ピンの間に抵抗を入れ、足の短い方をGNDに繋ぐだけです。
 単色LEDは赤外線が送信されていることを肉眼で確認するためです。


4:送受信の確認
 受信側、送信側のどちらも準備ができたら、両方とも電源を入れて赤外線LEDが赤外線受光器に当たるようにします。
 すると以下のような値が受信側のシリアルモニタに表示されるはずです。(以下の例では2回送信しています)
f:id:rikoubou:20170612141632p:plain

 一番最初の大きな値は無視します。それ以降はdataに設定した値とほぼ同じ値が送信されていることがわかります。
 何度か試した感じでは、誤差は最大で±20程度のようです。またdataとして送る一つの信号の長さは長い方が(1000以上ぐらい)の方が良いようです。


 以上、ESP32を使っての赤外線通信についてでした。


■参考記事
Arduinoで赤外線リモコンの信号を解析する
Arduinoで赤外線リモコン信号を発信する

【ESP32】スリープモードについて

 前に作成した自作ゼルダエフェクトーンが電池の持ちがなさすぎたので、ESP32でのスリープモードについて調べました。


■スリープモードについて
 結論からとしては以下のプログラムで実装できます。

#include "esp_deep_sleep.h"

void setup() {
  Serial.begin(115200);
  Serial.println("start ESP32");
  Serial.println("config IO");
  
  // スリープのための諸々の設定(今回はGPIO0ピンを使う)
  esp_deep_sleep_pd_config(ESP_PD_DOMAIN_RTC_PERIPH, ESP_PD_OPTION_AUTO);
  gpio_pullup_en(GPIO_NUM_0);    // use pullup on GPIO
  gpio_pulldown_dis(GPIO_NUM_0); // not use pulldown on GPIO

  esp_deep_sleep_enable_ext0_wakeup(GPIO_NUM_0, 0); // 指定したGPIOがLowの時に起動

  delay(5000);
  Serial.println("deep sleep start!");
  esp_deep_sleep_start(); // スリープモード実行
}

void loop() {
  
}

 このプログラムをESP32に書き込んでからシリアルモニタを立ち上げ、「deep sleep start!」が表示されたあとにスリープモードに入ります。

 今回はGPIO0ピンをLowにすると起動するように設定しているので、GPIO0をGNDに落とすと再び「start ESP32」や「deep sleep start!」が表示されます。またesp_deep_sleep_enable_ext0_wakeup関数の第二引数を1にすると、GPIO0がHighの時に起動するというようにできます。

 色々な関数で使われている「GPIO_NUM_0」という引数の意味は、ESP32のライブラリで使用されている定数で、GPIO_NUM_0〜GPIO_NUM_40まであります。gpio_num_tの型エラーが出た場合はこの定数を使用します。

 今回はGPIOピンからの起動を行いましたが、時間による起動もできるようです。(参考記事より)

 実際に測定はしてないのでわかりませんが、スリープモードだとかなりの節約ができるみたいです。常時駆動させるような場合はスリープモードが必須になると思うので、ご参考になれば。

(一日に二回も更新するなんて偉いぞ、自分)


・参考記事
ESP32 Deep Sleep のテスト (Hibernation mode) - ブログ/こばさんの wakwak 山歩き
pcbreflux: ESP32 Deep Sleep Example

【ESP32】5Vピンについて

akizukidenshi.com

秋月で売られているこのESP32-DevKitC、回路図の例などを調べると3V3が電源というのは様々なサイトで書かれていますが、5Vと書かれたピンが何を意味しているのかを今まで知らなかったので今回メモしておきます。


■5Vピンの謎
 結論から言うと、5Vピンの先には3.3Vに降圧するレギュレーターが入っているので5V以上でも動きます。
(「3V3が電源」という内容で書かれた記事や回路図が多いので混乱しがちですが、USBからの給電が5Vなのでそれを降圧する必要がありレギュレーターは必須なのです……)

 上記商品ページにある回路図を見ると「NCP1117」というレギュレーターが使われています。そのデータシートは以下になります。

 NCP1117 pdf, NCP1117 ディスクリプション, NCP1117 データシート, NCP1117 view ::: ALLDATASHEET :::

 これを読むとどうやら20Vぐらいまではいけるようです(未検証)

 実験として8V程度を5Vピンに入れてやっても焼けることはなかったので、大丈夫です。ただしどれぐらい発熱するかはわからないので、6Vぐらいまでにしておいた方が良いかもしれません。

【ESP32】PWMでモーターを制御する方法

ESP32でPWM制御をやってみました。ESP32ではPWM用のピンがあるわけではなく、ソフト側でPWMの設定を行います。


1:ESP32でのPWMの使い方
 ledcSetup、ledcAttachPin、ledcWriteの関数を使用します。
 ledcSetupでPWMの設定、ledcAttachPinでチャンネルとピンを対応、ledcWriteで実行という流れです。

// 1:ledcSetup(チャンネル, 周波数, PWMの範囲);
ledcSetup(0, 490, 8);

// 2:ledcAttachPin(ピン番号, チャンネル);
ledcAttachPin(7, 0);

// 3:ledcWrite(チャンネル, PWM値);
ledcWrite(0, 255);

※ledcSetupでのPWMの範囲は、8(8bit)を設定した場合は0〜255、10(10bit)の場合は0〜1023になります。

 これでPWMの使い方がわかったので、ESP32でモーターの制御をやっていきます。


1:材料
・電池ボックス
電池ボックス 単3×2本 リード線・スイッチ付: パーツ一般 秋月電子通商 電子部品 ネット通販

・モータードライバ(半田付けが必要)
DRV8835使用ステッピング&DCモータドライバモジュール: 組立キット 秋月電子通商 電子部品 ネット通販

・モーター
DCモーター FA−130RA−2270: パーツ一般 秋月電子通商 電子部品 ネット通販

・単3電池2本


2:プログラム

/* 使うピンの定義 */
const int IN1 = 25;
const int IN2 = 26;

/* チャンネルの定義 */
const int CHANNEL_0 = 0;
const int CHANNEL_1 = 1;

const int LEDC_TIMER_BIT = 8;   // PWMの範囲(8bitなら0〜255、10bitなら0〜1023)
const int LEDC_BASE_FREQ = 490; // 周波数(Hz)
const int VALUE_MAX = 255;      // PWMの最大値

void setup() {
  pinMode(IN1, OUTPUT); // IN1
  pinMode(IN2, OUTPUT); // IN2

  // ピンのセットアップ
  ledcSetup(CHANNEL_0, LEDC_BASE_FREQ, LEDC_TIMER_BIT);
  ledcSetup(CHANNEL_1, LEDC_BASE_FREQ, LEDC_TIMER_BIT);

  // ピンのチャンネルをセット
  ledcAttachPin(IN1, CHANNEL_0);
  ledcAttachPin(IN2, CHANNEL_1);
}

void loop() {
  forward(255); // 正転
  delay(3000);
  coast();      // 空転
  delay(3000);
  reverse(100); // 逆転
  delay(3000);
  brake();      // ブレーキ
  delay(3000);
}

// 正転
void forward(uint32_t pwm) {
  if (pwm > VALUE_MAX) {
    pwm = VALUE_MAX;
  }
  ledcWrite(CHANNEL_0, pwm);
  ledcWrite(CHANNEL_1, 0);
}

// 逆転
void reverse(uint32_t pwm) {
  if (pwm > VALUE_MAX) {
    pwm = VALUE_MAX;
  }
  ledcWrite(CHANNEL_0, 0);
  ledcWrite(CHANNEL_1, pwm);
}

// ブレーキ
void brake() {
  ledcWrite(CHANNEL_0, VALUE_MAX);
  ledcWrite(CHANNEL_1, VALUE_MAX);
}

// 空転
void coast() {
  ledcWrite(CHANNEL_0, 0);
  ledcWrite(CHANNEL_1, 0);
}


3:回路図
f:id:rikoubou:20170605183739p:plain


 上記のように繋げばモーターが正転、逆転を始めます。PWMの値を変更すると、モーターの回転数も変化します。

 ESP32が3Vで駆動できるので、それに合わせて低い電圧でも動くモータードライバを選びました。基盤が熱くなると注意書きがありますが、3V程度の使用であれば問題はないようです。低電圧でも動くモータードライバもいいですね。

【ESP32】data.sparkfun.comにESP32から値を送る方法

data.sparkfun.com公式

「data.sparkfun.com」というIoT用の無料で使えるサイトを知ったのでESP32から値を送ってみました。今回はその方法をまとめていきます。

1:data.sparkfun.comでストリームを作成する
 data.sparkfun.comにアクセスし、createボタンを押します。移動先のページで各項目を入力することで値を送るストリームを作成できます。

項目名 内容 必須
Title 作成するストリームのページに表示されるタイトル
Description 作成するストリームのページの表示される詳細な説明
Show in Public Stream List? Visibleの場合は全体リストに公開、Hiddenの場合は非公開
Fields 値を受け取る変数名
Stream Alias エイリアスの設定。sensorと入力するとhttp://data.sparkfun.com/sensorでアクセスできる ×
Tags タグの設定 ×
Location 場所の設定 ×

上記の入力が終了しSaveボタンを押すと、必要なキーや値を送る例を表示したページに移動します。各値は忘れないようにメモしておきます。

ちなみに各項目の内容は以下の通りです。

項目名 内容
Public URL 作成されたストリームのURL。ここで送られた値を確認する
Public Key ストリームからデータを取り出す時に必要なキー
Private Key ストリームにデータを送る時に必要なキー
Delete Key ストリームを削除する時に必要なキー
Format ストリームにデータを送る時のフォーマット
Example Formatに合わせた具体例


2:ESP32をネット接続してストリームに値を送信する
1でストリームが完成したら、FormatにしたがってESP32からネット経由で値を送信します。具体的にはESP32に以下のソースを書き込めば実現できます。

・Sparkfun.ino

#include <WiFi.h>

const char* ssid     = "***";       // インターネットに接続できるWiFiのSSID
const char* password = "***";  // SSIDのパスワード

const char* publicKey = "*****";  // ストリーム作成時に払い出されたPublic Key
const char* privateKey = "*****"; // ストリーム作成時に払い出されたPrivate Key
const char* fields = "field";          // ストリーム作成時に設定したFields

const char* host = "data.sparkfun.com";  // host

WiFiClient client;

void setup() {
  Serial.begin(115200);
  
  // WiFiに接続
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)  {
    Serial.print(".");
    delay(1000);
  }
  Serial.print("Connected to ");
  Serial.println(ssid);

  if (client.connect(host, 80)) {
    int val = 100;  // 今回は100という数値を送信

    // Formatに合わせたURLを作成
    String url = String("/input/")
                  + publicKey + "?private_key="
                  + privateKey + "&" + fields + "=" + val;

    // URLを発行
    client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                 "Host: " + host + "\r\n\r\n");
    delay(1000);

    while (client.available()) {
      Serial.print(client.readStringUntil('¥r'));  // 結果のhtmlを表示
    }
  } else {
    Serial.println("Connection failed!");
  }
}

void loop() {
}

WiFiに接続した後に100という値を送信するURLを作成し発行します。その結果のhtmlをシリアルモニタに表示させています。


以上の方法で値をストリームに送信できます。ストリームから値を取得したり削除したりはまだ試していませんが、いわゆるIoTっぽいことがこれでできるようになります。ストリームを使って色々値のやりとりできたら楽しいですね。


※追記:ストリームからの値取得
ストリームからの値を取得することもできたので修正したソースを追記しておきます。

・Sparkfun2.ino

#include <WiFi.h>

const char* ssid     = "****";
const char* password = "****";
const char* publicKey = "*****";
const char* privateKey = "*****";
const char* fields = "field";
const char* host = "data.sparkfun.com";

WiFiClient client;

// 引数の値を送信する関数(全角文字はストリームに送信できない。失敗する)
void sendDataToSparkfun(String val) {
  String url = String("/input/")
                + publicKey + "?private_key="
                + privateKey + "&" + fields + "=" + val;
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
             "Host: " + host + "\r\n\r\n");
  // 結果を表示
  while (client.available()) {
    Serial.print(client.readStringUntil('¥r'));
  }
}

// ストリームの値を取得する関数
void getDataFromSparkfun() {
  String url = String("/output/") + publicKey + ".csv?page=1";
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                "Host: " + host + "\r\n\r\n");
  // 結果を表示
  while (client.available()) {
    Serial.print(client.readStringUntil('¥r'));
  }
}

void setup() {
  Serial.begin(115200);
  
  // WiFiに接続
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)  {
    Serial.print(".");
    delay(1000);
  }
  Serial.print("Connected to ");
  Serial.println(ssid);

  if (client.connect(host, 80)) {
    String value = "1111"; // 1111を送信
    sendDataToSparkfun(value);
    delay(1000);
    getDataFromSparkfun();
  } else {
    Serial.println("Connection failed!");
  }
}

void loop() {
}

Arduino IDEでのコンパイル時に特におかしなところがないのに「"関数名" was not declared in this scope」というエラーが発生した場合、setup関数よりも前にエラーが出た関数を移動させるとコンパイルが通るという現象もあるようです。

【ESP32】ESP32とスマホを接続してWiFiUDP通信する方法

rikoubou.hatenablog.com

↑の前回の記事でESP32を使って以降、ESP32をいじっています。今回はタイトル通り「ESP32とスマホを繋いでUDP通信する方法」をやってみたので記録しておきます。

1:ESP32とUDP通信できるようにする
基本的にはWiFiをアクセスポイント(APモード)で使用するプログラムを少し変更するだけでできます。以下がプログラムになります。

・ESP32_WiFiUDP.ino

#include <WiFi.h>
#include <WiFiUdp.h>

const char ssid[] = "ESP32_wifi"; // SSID
const char pass[] = "esp32pass";  // password
const int localPort = 10000;      // ポート番号

const IPAddress ip(192, 168, 4, 1);       // IPアドレス(ゲートウェイも兼ねる)
const IPAddress subnet(255, 255, 255, 0); // サブネットマスク

WiFiUDP udp;

void setup() {
  Serial.begin(115200);

  WiFi.softAP(ssid, pass);           // SSIDとパスの設定
  delay(100);                        // 追記:このdelayを入れないと失敗する場合がある
  WiFi.softAPConfig(ip, ip, subnet); // IPアドレス、ゲートウェイ、サブネットマスクの設定

  Serial.print("AP IP address: ");
  IPAddress myIP = WiFi.softAPIP();
  Serial.println(myIP);

  Serial.println("Starting UDP");
  udp.begin(localPort);  // UDP通信の開始(引数はポート番号)

  Serial.print("Local port: ");
  Serial.println(localPort);
}

void loop() {
  if (udp.parsePacket()) {
    Serial.println(udp.read()); // UDP通信で来た値を表示
  }
}

WiFiUdp.hを読み込んで使用します。ポート番号とIPアドレスは固定させていた方が良いと思います。

上記のプログラムを書き込むとSSIDで指定した名前でWiFiが飛ぶようになります。passwordで設定したパスを入力すれば接続できます。


2:スマホにアプリを入れてUDPコントローラを作成する
次にスマホUDPコントローラとして使うためのアプリ「WiFi TCP/UDP Controller」を以下のリンクからインストールします。
play.google.com


インストール後にWiFi TCP/UDP Controllerを立ち上げるとDEFと書かれた多くのボタンが表示されます。最初は何も設定されていないので、右上にある「PREFERENCE」をタップして各ボタンの設定を行います。

f:id:rikoubou:20170531180529p:plain

・IP or Domain Name
 IPアドレスドメイン名を設定します。1のプログラムそのままの場合は「192.168.4.1」と設定します。

・Port
 ポート番号を設定します。1のプログラムそのままの場合は「10000」と設定します。

・BUTTON Name
 画面に表示されるボタン名を設定します。設定画面に移動したときに出てくる画像通りの並び順なので、それぞれのボタンに表示させたい名前を設定します。自分の場合は以下のように設定しました。

ボタン名 表示名
button2
button4 ◀︎
button6 ▶︎
button8
button19 B
button21 A

・BUTTON Command
 ボタンを押した際に送信する値を設定します。設定画面に移動したときに出てくる画像通りの並び順なので、それぞれのボタンに表示させたい名前を設定します。ASCII-HEXでは文字列を送信する場合は「ASCII」、数値を送信する場合は「HEX」を選びます。

自分の場合は以下のように設定しました。

項目名 設定値
ASCII-HEX ASCII
button2 0
button4 1
button6 2
button8 3
button19 4
button21 5

 STOP COMMANDではボタンを離したときに送信される値を設定します。自分の場合は以下のように設定しました。

項目名 設定値
button2 6
button4 6
button6 6
button8 6
button19 6
button21 6

・BUTTON Visibility
 ボタンの表示/非表示を設定します。デフォルトでは全てのボタンが表示されているので、不要なボタンは非表示にします。自分の場合は以下のように設定しました。

項目名 チェック
button2
button4
button6
button8
button19
button21

上記以外のチェックは全て外しています。

・BUTTON Repeatable
 ボタンを押している間の送信時間間隔を設定します。個別のボタンごとに設定もできますが、自分の場合は以下のように設定しました。

項目名 設定値
Individual Intervals OFF
Interval(ms) 200

・Send Data
 送った値を画面下に表示させるかどうかを設定します。自分の場合はONにしています。

・設定完了例
 自分が作成したコントローラは以下のようになります。各ボタンを押したときに上にある数字が送信されます。全てのボタンにおいて離したときに6が送信されるようにしています。
f:id:rikoubou:20170531181547p:plain


3:ESP32とスマホを接続して通信を確認する
1のプログラムを書き込んだESP32をUSBで接続し、シリアルモニタを立ち上げます。ESP32のSSIDWiFiスマホで接続し、2で作成したコントローラのボタンを押すとその値がシリアルモニタに表示されます。(今回はASCIIで送信しており、数字の文字列が送信されているので、ASCIIの対応表で数字を変換してください)

・このような形で押したボタンの値が表示されていきます。
f:id:rikoubou:20170531185704p:plain


以上でESP32とスマホ間でのUDP通信ができました。
ESP32にディスプレイを繋げば簡単なゲームも作成できる(している方もいる)ので色々と面白いことができそうです。


・参考資料
github.com

www.nicovideo.jp